Доброе время суток
Подскажите, как добавить в контекстное меню Excel еще один пунктик, и при его выборе заносить в выбранную ячейку какое-то значение.
Заранее спасибо.

Здравствуйте, rol, Вы писали:

rol>Доброе время суток
rol>Подскажите, как добавить в контекстное меню Excel еще один пунктик, и при его выборе заносить в выбранную ячейку какое-то значение.
rol> Заранее спасибо.

Ну, например, в контекстное меню для ячейки (контекстных меню в Excel много)

в модуле листа:

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    Dim ctrl As CommandBarControl
    For Each ctrl In Application.CommandBars("Cell").Controls
        If ctrl.Tag = "MY" Then
            Application.CommandBars("Cell").Controls(ctrl.Caption).Delete
        End If
    Next ctrl
    
    If Target.Cells.Count = 1 Then
        With Application.CommandBars("Cell").Controls.Add _
            (Type:=msoControlButton, Temporary:=True)
            .Tag = "MY"
            .BeginGroup = True
            .Caption = "Test"
            .OnAction = "Test"
        End With
    End If
End Sub

в простом модуле:

Sub Test()
    ActiveCell = "Test"
End Sub