_C_>Поможите, будьте любезны, очень надо. без него портировать — сутками mutablы писать — не хватит сил.

macro @:=(lhs, rhs)
{
    <[ def $lhs = $rhs ]>
}

namespace ShortDef
{
  [assembly: Nemerle.Internal.OperatorAttribute ("ShortDef", ":=",     false, 141, 140)]
  macro @:=(name, value)
  {
    <[ def $name = $value ]>
  }
}

    qwerqwer := 123;
    WriteLine(qwerqwer);

C>macro @:=(lhs, rhs)
C>{
C>    <[ def $lhs = $rhs ]>
C>}
C>

[assembly: Nemerle.Internal.OperatorAttribute ("пространство имен где объявлен макрос", ":=",     false, 141, 140)]

_C_>если кто знает, как это спросить в макросе, поделитесь

    def typer = Nemerle.Macros.ImplicitCTX();

    def locals = typer.LocalContext.GetLocals();

using Nemerle;
using Nemerle.Collections;
using Nemerle.Compiler;
using Nemerle.Compiler.Parsetree;
using Nemerle.Compiler.Typedtree;
using Nemerle.Text;
using Nemerle.Utility;

using System;
using System.Collections.Generic;
using System.Linq;

[assembly: Nemerle.Internal.OperatorAttribute ("PythonLike", ":=", false, 141, 140)]

namespace PythonLike
{
  macro @:=(expr1 : PExpr, expr2 : PExpr)
  {
    PythonAssignImpl.DoTransform(Macros.ImplicitCTX(), expr1, expr2)
  }
  
  module PythonAssignImpl
  {
    public DoTransform(typer : Typer, expr1 : PExpr, expr2 : PExpr) : PExpr
    {
      match (expr1)
      {
        | <[ $(n : name) ]> => 
          // Пытаемся найти поля в текущем объекте с именем n.
          def members = typer.CurrentTypeBuilder.LookupMember(n.Id, false);
          
          // пытаемся найти локальную переменную с именем n
          match (typer.LocalContext.FindLocal(n))
          {
            | Some(var) when var.IsMutable => <[ $expr1 = $expr2 ]> 
            | Some(var)                    => 
              // Здесь можно было бы объявлять новую неизменяемую переменную, но это вообще пипец какие грабли! 
              Message.Error(expr1.Location, $"In this context already defined immutable variable '$n'.");
              Message.Hint(var.Location, "Previous declaration.");
              <[ () ]>
            
            | None when members.IsEmpty    => <[ mutable $expr1 = $expr2 ]>
            | None                         => <[ $expr1 = $expr2 ]>
          }
        
        | _ => Message.FatalError(expr1.Location, "Expected simple name.");
      }
    }
  }
}

using System.Console;
using PythonLike;

module Program
{
  //mutable x : int = 1;
  
  Main() : void
  {
    //def x = 1;
    x := 23;
    WriteLine(x);
    x := 42;
    WriteLine(x);
    _ = ReadLine();
  }
}