[Nemerle.MacroUsage (Nemerle.MacroPhase.WithTypedMembers,
                       Nemerle.MacroTargets.Class,
                       Inherited = false, AllowMultiple = false)]
  macro StructuralEquality (tb : TypeBuilder)
  {
    def fields = tb.GetFields(BindingFlags.Public %| BindingFlags.NonPublic %|
                             BindingFlags.Instance %| BindingFlags.DeclaredOnly);

    def invokeEquals(x : IField)
    {
      def nm = Macros.UseSiteSymbol(x.Name);
      if(x.GetMemType().IsValueType)
        <[ $(nm : name).Equals(other.$(nm : name)) ]>
      else
        <[ System.Collections.Generic.EqualityComparer.Default.Equals($(nm : name), other.$(nm : name)) ]>;
    }

    def body = match(fields)
    {
      | []       => <[ true ]>
      | [single] => invokeEquals(single)
      | first :: others =>
        others.FoldLeft(invokeEquals(first), (field, acc) => <[ $acc && $(invokeEquals(field)) ]>)
    }

    tb.Define(<[ decl:
      public override Equals (_ : System.Object) : bool
      {
        | null => false
        | x when x.GetType().Equals(this.GetType()) =>
          def other = x :> $(tb.ParsedTypeName);
          $body
        | _ => false
      }
    ]>);
  }