Задача:

1. Отбилдить MVC сайт
2. Запустить операцию паблишинга, как в VS "Publish"
3. результат запихнуть в зип-файл

И все это через коммандную строку. С первым и третьим пунктом в принципе все ясно, но никак не могу найти именно операцию паблишинга. Ни в msbuild, ни в devenv, ни в asp_compiler.

Здравствуйте, Andrey Rubayko, Вы писали:

AR>2. Запустить операцию паблишинга, как в VS "Publish"
AR>И все это через коммандную строку. С первым и третьим пунктом в принципе все ясно, но никак не могу найти именно операцию паблишинга. Ни в msbuild, ни в devenv, ни в asp_compiler.
С другими типами проектов работало так:
msbuild.exe MyCoolProject.csproj /target:Publish

Ещё можно сделать отдельную конфигурацию для билда со включённым publish и билдить всё в ней через devenv.exe c явным указанием конфига

Здравствуйте, Andrey Rubayko, Вы писали:


Можно например так:


set deploy_dir=c:\temp\Deploy
set compilerPath=C:\WINDOWS\Microsoft.NET\Framework\v4.0.30319\
set "winrar_dir=C:\Program Files\WinRAR"

set config_file=test_web_config
set distrib_file=MvcAppTestDistr

set deploy_dir_web=%deploy_dir%\MvcApp_test_web

%compilerPath%aspnet_compiler.exe -v /MyApp -p ".." -f -u "%deploy_dir_web%"
rem с MyApp возможно придется пошаманить

xcopy /Y "DeployFiles\%config_file%" %deploy_dir_web%\web.config

if exist "%deploy_dir%\%distrib_file%.rar" (
del /q "%deploy_dir%\%distrib_file%.rar"
)

set TEMP_ARCHIVE="%deploy_dir%\%distrib_file%.rar"

"%winrar_dir%\WinRAR.exe" a -ep1 -s "%TEMP_ARCHIVE%" "%deploy_dir_web%"

rem читаем/пишем значение из ini файла
set SETTINGSFILE="%CD%\DeployFiles\settings.ini"

for /f "eol=# delims== tokens=1,2" %%i in ('type "%SETTINGSFILE%"') do (
set %%i=%%j
)

set /a NEW_VER=%ver%+1

echo ver=%NEW_VER% > %SETTINGSFILE%

ren %TEMP_ARCHIVE% %distrib_file%_v%NEW_VER%.rar

explorer "%deploy_dir%"