Здравствуйте, _hunter, Вы писали:

S>>В каком смысле завершения? Что за компонент?

_>в моем случае форма запускает процесс(при запуске она должна заснуть) и при завершении этого процесса форма должна проснутся.

Полностью "заснувшая" форма производит впечатление умершей.
IMHO, проще модально показать "ожидающую форму", примерно такую:

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls;

type
  TForm2 = class(TForm)
    ..
  private
    { Private declarations }
    ncount : DWord;
    FHandles: array [0..MAXIMUM_WAIT_OBJECTS-1] of THandle;
    procedure WMUser(var msg: TMessage); message WM_USER;
  public
    function WaitHandles(const Handles: array of THandle): Longint; virtual;
    { Public declarations }
  end;

const
  IDWAIT = 256;

implementation

{$R *.DFM}

procedure TForm2.WMUser;
var
  waitresult: DWord;
begin
  Application.ProcessMessages;
  if (ModalResult <> 0) then
    Exit;

  waitresult := MsgWaitForMultipleObjects( ncount,
                                           FHandles,
                                           False,
                                           INFINITE,
                                           QS_ALLINPUT );
                                           
  if (waitresult = WAIT_OBJECT_0 + ncount) then
    PostMessage(Handle, WM_USER, 0, 0)
  else
    ModalResult := IDWAIT + waitresult;
end;

function TForm2.WaitHandles;
begin
  ncount := High(Handles)-Low(Handles)+1;
  Move(Handles[0], FHandles[0], ncount* SizeOf(THandle));
  PostMessage(Handle, WM_USER, 0, 0);
  Result := ShowModal;
end;

Убирем форму из списка автосоздаваемых, а показывать будем так

 with TForm2.Create(nil) do
   try
     case WaitHandles([pi.hProcess]) of
       IDCANCEL: {форма закрыта кнопкой} ;
       ..
       IDWAIT+WAIT_FAILED: {Ошибка функции ожидания};
       ..
       IDWAIT+WAIT_OBJECT_0: {Сигналит hProcess};
       ..
     end;
   finally
     Free;
   end;